使用asp在iis创建web站点的函数
'=============================================================
'函数介绍：创建website
'本函数使用adsi，需要administrators组用户权限
'函数名称：createwebsite(computer,ipaddr,portnum,hostname,websitedirectory,logdirectory,websiteinfo,guestusername,guestuserpass,startorstop)
'用法：createwebsite 计算机名(一搬为localhost或127.0.0.1),站点ip地址,端口号,主机名,站点根目录,,log文件的目录站点说明,网站访问时所使用的帐号,网站访问时所用帐号的口令,是否启动站点
'例：createwebsite "localhost","127.0.0.123","80","www.test.net","e:\userdata\usernum001","e:\userdata\usernum001\logfiles","wwwtest.net","iusr_num001_test.net","abc888",true
'=============================================================
function createwebsite(computer,ipaddr,portnum,hostname,websitedirectory,logdirectory,websiteinfo,guestusername,guestuserpass,startorstop)
dim w3svc, webserver, newwebserver, newdir
dim bindings, bindingstring, newbindings, sitenum, siteobj, bdone
on error resume next
err.clear
'检测是否能够加载w3svc服务（即web服务）
set w3svc = getobject("iis://" & computer & "/w3svc")
if err.number <> 0 then '显示错误提示
  response.write "无法打开: "&"iis://" & computer & "/w3svc"
  response.end
end if
'检测是否有设定相同ip地址、端口及主机名的站点存在
bindingstring = ipaddr & ":" & portnum & ":" & hostname
for each webserver in w3svc
  if webserver.class = "iiswebserver" then
  bindings = webserver.serverbindings
   if bindingstring = bindings(0) then
    response.write "ip地址冲突:" & ipaddr & ",请检测ip地址！."
    exit function
   end if
  end if
next

'确定一个不存在的站点编号做为新建站点编号，系统默认website站点编号为1，因此从2开始
sitenum=2
bdone = false
while (not bdone)
err.clear
set siteobj = getobject("iis://"&computer&"/w3svc/"&sitenum) '加载指定站点
if (err.number = 0) then
  'response.write " step_1站点"&sitenum&"存在"
  sitenum = sitenum + 1
else
  'response.write " step_1站点"&sitenum&"不存在"
  err.clear
  set newwebserver = w3svc.create("iiswebserver",sitenum) '创建指定站点
  if (err.number <> 0) then
   'response.write " step_2站点"&sitenum&"创建失败"
   sitenum = sitenum + 1
  else
   'response.write " step_2站点"&sitenum&"创建成功"
   bdone = true
  end if
end if
if (sitenum > 50) then '服务器最大创建站点数
  response.write "超出服务器最大创建站点数，正在创建的站点的序号为： "&sitenum&"."
  response.end
end if
wend

'进行站点基本配置
newbindings = array(0)
newbindings(0) = bindingstring
newwebserver.serverbindings = newbindings
newwebserver.servercomment= websiteinfo
newwebserver.anonymoususername= guestusername
newwebserver.anonymoususerpass= guestuserpass
newwebserver.keytype = "iiswebserver"
newwebserver.frontpageweb = true
newwebserver.enabledefaultdoc = true
newwebserver.defaultdoc = "default.htm, default.asp, index.htm, index.asp"
newwebserver.logfiledirectory= logdirectory
newwebserver.setinfo
set newdir = newwebserver.create("iiswebvirtualdir", "root")
newdir.path = websitedirectory
newdir.accessread = true
newdir.appfriendlyname = "应用程序" & websiteinfo
newdir.appcreate true
newdir.accessscript = true
err.clear
newdir.setinfo
if (err.number <> 0) then
  response.write "主目录创建时出错."
  response.end
end if
if startorstop = true then
  err.clear
  set newwebserver = getobject("iis://" & computer & "/w3svc/" & sitenum)
  newwebserver.start
  if err.number <> 0 then
   response.write "启动站点时出错!"
   response.end
   err.clear
  end if
end if
response.write "站点创建成功，站点编号为："& sitenum &" ，域名为："& hostname
end function

使用asp删除指定iis站点
'=============================================================
'函数介绍：删除指定iis站点
'本函数使用adsi，需要administrators组用户权限
'函数名称：delwebsite (computer,sitenum)
'用法：delwebsite 计算机名，站点编号
'例：delwebsite "127.0.0.1","2"
'=============================================================
function delwebsite(computer,sitenum)
set w3svc = getobject("iis://"&computer&"/w3svc")
w3svc.delete "iiswebserver",sitenum
response.write "删除成功！"
end function

function edituser(computer,username,oldpassword,password,fullname,info)
'读取用户信息
set changeuserobj = getobject("winnt://"&computer&"/"&username&",user")
'修改帐号密码
if password<>"" then
  changeuserobj.setpassword password
  response.write "帐号密码修改成功！<br>"
end if
'修改帐号全名
if fullname<>"" then
  userfullname = changeuserobj.get("fullname")
  changeuserobj.fullname = fullname
  changeuserobj.setinfo
  response.write "帐号全名修改成功！<br>"
end if
'修改帐号说明
if info<>"" then
  userfullname = changeuserobj.get("description")
  changeuserobj.description = info
  changeuserobj.setinfo
  response.write "帐号说明修改成功！<br>"
end if
set changeuserobj=nothing
end function

function deluser(computer,username)
set deluserobj = getobject("winnt://"&computer&"/"&username)
if err = &h800401e4 then
  response.write "用户"&username&"不存在"
  response.end
end if
set delobj = getobject(deluserobj.parent)
delobj.delete "user", deluserobj.name
set deluserobj = nothing
set delobj = nothing
response.write "删除成功"
end function

使用asp列出nt用户组及用户

'=============================================================
'函数介绍：列出nt用户组及用户
'本函数使用adsi，需要administrators组用户权限
'函数名称：listgroup(computer)
'用法：listgroup(计算机名称)
'例：显示127.0.0.1计算机nt用户组及用户
'listgroup "127.0.0.1"
'=============================================================
function listgroup(computer)
response.write "<p><b>以下为计算机"&computer&"系统用户组及用户列表</b></p>"
set computerobj = getobject("winnt://"&computer)
computerobj.filter = array("group")
for each member in computerobj
  response.write "用户组："&member.name&"<br>"
  listuser computer,member.name
next
end function

'列出指定用户组用户
function listuser(computer,group)
set userobj = getobject("winnt://"&computer&"/"&group)
for each member in userobj.members
  response.write "&nbsp;&nbsp;&nbsp;&nbsp;组中用户："&member.name &"<br>"
next
end function